public abstract class Closure<V> extends GroovyObjectSupport implements Cloneable, GroovyCallable, Runnable, Serializable
Represents any closure object in Groovy.
Groovy allows instances of Closures to be called in a short form. For example:
def a = 1
def c = { a }
assert c() == 1
To be able to use a Closure in this way with your own subclass, you need to provide a doCall method with any signature you want to. This ensures that getMaximumNumberOfParameters() and getParameterTypes() will work too without any additional code. If no doCall method is provided a closure must be used in its long form like def a = 1
def c = {a}
assert c.call() == 1
| Modifiers | Name | Description |
|---|---|---|
static int | DELEGATE_FIRST | With this resolveStrategy set the closure will attempt to resolve property references and methods to the delegate first then the owner. |
static int | DELEGATE_ONLY | With this resolveStrategy set the closure will resolve property references and methods to the delegate only and entirely bypass the owner. |
static int | DONE | |
static Closure | IDENTITY | |
static int | OWNER_FIRST | With this resolveStrategy set the closure will attempt to resolve property references and methods to the owner first, then the delegate (this is the default strategy). |
static int | OWNER_ONLY | With this resolveStrategy set the closure will resolve property references and methods to the owner only and not call the delegate at all. |
static int | TO_SELF | With this resolveStrategy set the closure will resolve property references to itself and go through the usual MetaClass look-up process. |
protected int | maximumNumberOfParameters | |
protected Class[] | parameterTypes |
| Type Params | Return Type | Name and description |
|---|---|---|
<W> | public Closure<W> | andThen(Closure<W> other)Alias for rightShift(Closure) |
| public Closure<V> | andThenSelf()Call andThen(Closure) on this. |
| public Closure<V> | andThenSelf(int times)Call andThen(Closure) on this exactly times times. |
| public Closure | asWritable()
|
| public V | call()Invokes the closure with no arguments, returning any value if applicable. |
| public V | call(Object arguments)Invokes the closure with given argument(s), returning any value if applicable. |
| public V | call(Object arguments)Invokes the closure with given argument(s), returning any value if applicable. |
| public Object | clone() |
| public Closure<V> | compose(Closure other)Alias for leftShift(Closure) |
| public Closure<V> | composeSelf()Call compose(Closure) on this. |
| public Closure<V> | composeSelf(int times)Call compose(Closure) on this exactly times times. |
| public Closure<V> | curry(Object arguments)Support for Closure currying. |
| public Closure<V> | curry(Object argument)Support for Closure currying. |
| public Closure<V> | dehydrate()Returns a copy of this closure where the "owner", "delegate" and "thisObject" fields are null, allowing proper serialization when one of them is not serializable. |
| public Object | doCall(Object args) |
| public Object | getDelegate()
|
| public int | getDirective()
|
| public int | getMaximumNumberOfParameters()
|
| public Object | getOwner()
|
| public Class[] | getParameterTypes()
|
| public Object | getProperty(String property) |
| public int | getResolveStrategy()Gets the strategy which the closure uses to resolve methods and properties |
| public Object | getThisObject() |
| public boolean | isCase(Object candidate) |
| public Closure<V> | leftShift(Closure other)Support for Closure reverse composition. |
| public V | leftShift(Object arg)Alias for calling a Closure for non-closure arguments. |
| public Closure<V> | memoize()Creates a caching variant of the closure. |
| public Closure<V> | memoizeAtLeast(int protectedCacheSize)Creates a caching variant of the closure with automatic cache size adjustment and lower limit on the cache size. |
| public Closure<V> | memoizeAtMost(int maxCacheSize)Creates a caching variant of the closure with upper limit on the cache size. |
| public Closure<V> | memoizeBetween(int protectedCacheSize, int maxCacheSize)Creates a caching variant of the closure with automatic cache size adjustment and lower and upper limits on the cache size. |
| public Closure<V> | ncurry(int n, Object arguments)Support for Closure currying at a given index. |
| public Closure<V> | ncurry(int n, Object argument)Support for Closure currying at a given index. |
| public Closure<V> | rcurry(Object arguments)Support for Closure "right" currying. |
| public Closure<V> | rcurry(Object argument)Support for Closure "right" currying. |
| public Closure<V> | rehydrate(Object delegate, Object owner, Object thisObject)Returns a copy of this closure for which the delegate, owner and thisObject are replaced with the supplied parameters. |
<W> | public Closure<W> | rightShift(Closure<W> other)Support for Closure forward composition. |
| public void | run() |
| public void | setDelegate(Object delegate)Allows the delegate to be changed such as when performing markup building |
| public void | setDirective(int directive)
|
| public void | setProperty(String property, Object newValue) |
| public void | setResolveStrategy(int resolveStrategy)Sets the strategy which the closure uses to resolve property references and methods. |
| protected static Object | throwRuntimeException(Throwable throwable) |
| public Closure<V> | trampoline(Object args)Builds a trampolined variant of the current closure. |
| public Closure<V> | trampoline()Builds a trampolined variant of the current closure. |
| Methods inherited from class | Name |
|---|---|
class GroovyObjectSupport | getMetaClass, setMetaClass |
With this resolveStrategy set the closure will attempt to resolve property references and methods to the delegate first then the owner. For example the following code:
class Test {
def x = 30
def y = 40
def run() {
def data = [ x: 10, y: 20 ]
def cl = { y = x + y }
cl.delegate = data
cl.resolveStrategy = Closure.DELEGATE_FIRST
cl()
assert x == 30
assert y == 40
assert data == [x:10, y:30]
}
}
new Test().run()
This will succeed, because the x and y variables declared in the delegate shadow the fields in the owner class.Note that local variables are always looked up first, independently of the resolution strategy.
With this resolveStrategy set the closure will resolve property references and methods to the delegate only and entirely bypass the owner. For example the following code :
class Test {
def x = 30
def y = 40
def z = 50
def run() {
def data = [ x: 10, y: 20 ]
def cl = { y = x + y + z }
cl.delegate = data
cl.resolveStrategy = Closure.DELEGATE_ONLY
cl()
println x
println y
println data
}
}
new Test().run()
will throw an error because even if the owner declares a "z" field, the resolution strategy will bypass lookup in the owner.Note that local variables are always looked up first, independently of the resolution strategy.
With this resolveStrategy set the closure will attempt to resolve property references and methods to the owner first, then the delegate (this is the default strategy). For example the following code:
class Test {
def x = 30
def y = 40
def run() {
def data = [ x: 10, y: 20 ]
def cl = { y = x + y }
cl.delegate = data
cl()
assert x == 30
assert y == 70
assert data == [x:10, y:20]
}
}
new Test().run()
Will succeed, because the x and y fields declared in the Test class shadow the variables in the delegate.Note that local variables are always looked up first, independently of the resolution strategy.
With this resolveStrategy set the closure will resolve property references and methods to the owner only and not call the delegate at all. For example the following code :
class Test {
def x = 30
def y = 40
def run() {
def data = [ x: 10, y: 20, z: 30 ]
def cl = { y = x + y + z }
cl.delegate = data
cl.resolveStrategy = Closure.OWNER_ONLY
cl()
println x
println y
println data
}
}
new Test().run()
will throw "No such property: z" error because even if the z variable is declared in the delegate, no lookup is made.Note that local variables are always looked up first, independently of the resolution strategy.
With this resolveStrategy set the closure will resolve property references to itself and go through the usual MetaClass look-up process. This means that properties and methods are neither resolved from the owner nor the delegate, but only on the closure object itself. This allows the developer to override getProperty using ExpandoMetaClass of the closure itself.
Note that local variables are always looked up first, independently of the resolution strategy.
Constructor used when the "this" object for the Closure is null. This is rarely the case in normal Groovy usage.
owner - the Closure ownerAlias for rightShift(Closure)
Call andThen(Closure) on this.
Call andThen(Closure) on this exactly times times.
times - the number of times to reverse compose the closure with itselfInvokes the closure with no arguments, returning any value if applicable.
Invokes the closure with given argument(s), returning any value if applicable.
arguments - could be a single value or a List of valuesInvokes the closure with given argument(s), returning any value if applicable.
Alias for leftShift(Closure)
Call compose(Closure) on this.
Call compose(Closure) on this exactly times times.
times - the number of times to compose the closure with itselfSupport for Closure currying.
Typical usage:
def multiply = { a, b -> a * b }
def doubler = multiply.curry(2)
assert doubler(4) == 8
Note: special treatment is given to Closure vararg-style capability. If you curry a vararg parameter, you don't consume the entire vararg array but instead the first parameter of the vararg array as the following example shows: def a = { one, two, Object[] others -> one + two + others.sum() }
assert a.parameterTypes.name == ['java.lang.Object', 'java.lang.Object', '[Ljava.lang.Object;']
assert a(1,2,3,4) == 10
def b = a.curry(1)
assert b.parameterTypes.name == ['java.lang.Object', '[Ljava.lang.Object;']
assert b(2,3,4) == 10
def c = b.curry(2)
assert c.parameterTypes.name == ['[Ljava.lang.Object;']
assert c(3,4) == 10
def d = c.curry(3)
assert d.parameterTypes.name == ['[Ljava.lang.Object;']
assert d(4) == 10
def e = d.curry(4)
assert e.parameterTypes.name == ['[Ljava.lang.Object;']
assert e() == 10
assert e(5) == 15
arguments - the arguments to bindSupport for Closure currying.
argument - the argument to bindReturns a copy of this closure where the "owner", "delegate" and "thisObject" fields are null, allowing proper serialization when one of them is not serializable.
Gets the strategy which the closure uses to resolve methods and properties
Support for Closure reverse composition.
Typical usage:
def times2 = { a -> a * 2 }
def add3 = { a -> a + 3 }
def addThenTimes = times2 << add3
// equivalent: addThenTimes = { a -> times2(add3(a)) }
assert addThenTimes(3) == 12
other - the Closure to compose with the current ClosureAlias for calling a Closure for non-closure arguments.
Typical usage:
def times2 = { a -> a * 2 }
def add3 = { a -> a + 3 }
assert add3 << times2 << 3 == 9
arg - the argument to call the closure withCreates a caching variant of the closure. Whenever the closure is called, the mapping between the parameters and the return value is preserved in cache making subsequent calls with the same arguments fast. This variant will keep all cached values forever, i.e. till the closure gets garbage-collected. The returned function can be safely used concurrently from multiple threads, however, the implementation values high average-scenario performance and so concurrent calls on the memoized function with identical argument values may not necessarily be able to benefit from each other's cached return value. With this having been mentioned, the performance trade-off still makes concurrent use of memoized functions safe and highly recommended. The cache gets garbage-collected together with the memoized closure.
Creates a caching variant of the closure with automatic cache size adjustment and lower limit on the cache size. Whenever the closure is called, the mapping between the parameters and the return value is preserved in cache making subsequent calls with the same arguments fast. This variant allows the garbage collector to release entries from the cache and at the same time allows the user to specify how many entries should be protected from the eventual gc-initiated eviction. Cached entries exceeding the specified preservation threshold are made available for eviction based on the LRU (Last Recently Used) strategy. Given the non-deterministic nature of garbage collector, the actual cache size may grow well beyond the limits set by the user if memory is plentiful. The returned function can be safely used concurrently from multiple threads, however, the implementation values high average-scenario performance and so concurrent calls on the memoized function with identical argument values may not necessarily be able to benefit from each other's cached return value. Also the protectedCacheSize parameter might not be respected accurately in such scenarios for some periods of time. With this having been mentioned, the performance trade-off still makes concurrent use of memoized functions safe and highly recommended. The cache gets garbage-collected together with the memoized closure.
protectedCacheSize - Number of cached return values to protect from garbage collectionCreates a caching variant of the closure with upper limit on the cache size. Whenever the closure is called, the mapping between the parameters and the return value is preserved in cache making subsequent calls with the same arguments fast. This variant will keep all values until the upper size limit is reached. Then the values in the cache start rotating using the LRU (Last Recently Used) strategy. The returned function can be safely used concurrently from multiple threads, however, the implementation values high average-scenario performance and so concurrent calls on the memoized function with identical argument values may not necessarily be able to benefit from each other's cached return value. With this having been mentioned, the performance trade-off still makes concurrent use of memoized functions safe and highly recommended. The cache gets garbage-collected together with the memoized closure.
maxCacheSize - The maximum size the cache can grow toCreates a caching variant of the closure with automatic cache size adjustment and lower and upper limits on the cache size. Whenever the closure is called, the mapping between the parameters and the return value is preserved in cache making subsequent calls with the same arguments fast. This variant allows the garbage collector to release entries from the cache and at the same time allows the user to specify how many entries should be protected from the eventual gc-initiated eviction. Cached entries exceeding the specified preservation threshold are made available for eviction based on the LRU (Last Recently Used) strategy. Given the non-deterministic nature of garbage collector, the actual cache size may grow well beyond the protected size limits set by the user, if memory is plentiful. Also, this variant will never exceed in size the upper size limit. Once the upper size limit has been reached, the values in the cache start rotating using the LRU (Last Recently Used) strategy. The returned function can be safely used concurrently from multiple threads, however, the implementation values high average-scenario performance and so concurrent calls on the memoized function with identical argument values may not necessarily be able to benefit from each other's cached return value. Also the protectedCacheSize parameter might not be respected accurately in such scenarios for some periods of time. With this having been mentioned, the performance trade-off still makes concurrent use of memoized functions safe and highly recommended. The cache gets garbage-collected together with the memoized closure.
protectedCacheSize - Number of cached return values to protect from garbage collectionmaxCacheSize - The maximum size the cache can grow toSupport for Closure currying at a given index. Parameters are supplied from index position "n". Typical usage:
def caseInsensitive = { a, b -> a.toLowerCase() <=> b.toLowerCase() } as Comparator
def caseSensitive = { a, b -> a <=> b } as Comparator
def animals1 = ['ant', 'dog', 'BEE']
def animals2 = animals1 + ['Cat']
// curry middle param of this utility method:
// Collections#binarySearch(List list, Object key, Comparator c)
def catSearcher = Collections.&binarySearch.ncurry(1, "cat")
[[animals1, animals2], [caseInsensitive, caseSensitive]].combinations().each{ a, c ->
def idx = catSearcher(a.sort(c), c)
print a.sort(c).toString().padRight(22)
if (idx < 0) println "Not found but would belong in position ${-idx - 1"}
else println "Found at index $idx"
}
// =>
// [ant, BEE, dog] Not found but would belong in position 2
// [ant, BEE, Cat, dog] Found at index 2
// [BEE, ant, dog] Not found but would belong in position 2
// [BEE, Cat, ant, dog] Not found but would belong in position 3
The position of the curried parameters will be calculated eagerly and implies all arguments prior to the specified n index are supplied. Default parameter values prior to the n index will not be available.n - the index from which to bind parameters (may be -ve in which case it will be normalized)arguments - the arguments to bindSupport for Closure currying at a given index.
argument - the argument to bindSupport for Closure "right" currying. Parameters are supplied on the right rather than left as per the normal curry() method. Typical usage:
def divide = { a, b -> a / b }
def halver = divide.rcurry(2)
assert halver(8) == 4
The position of the curried parameters will be calculated lazily, for example, if two overloaded doCall methods are available, the supplied arguments plus the curried arguments will be concatenated and the result used for method selection.arguments - the arguments to bindSupport for Closure "right" currying.
argument - the argument to bindReturns a copy of this closure for which the delegate, owner and thisObject are replaced with the supplied parameters. Use this when you want to rehydrate a closure which has been made serializable thanks to the dehydrate() method.
delegate - the closure delegateowner - the closure ownerthisObject - the closure "this" objectSupport for Closure forward composition.
Typical usage:
def times2 = { a -> a * 2 }
def add3 = { a -> a + 3 }
def timesThenAdd = times2 >> add3
// equivalent: timesThenAdd = { a -> add3(times2(a)) }
assert timesThenAdd(3) == 9
other - the Closure to compose with the current ClosureAllows the delegate to be changed such as when performing markup building
delegate - the new delegatedirective - The directive to set.Sets the strategy which the closure uses to resolve property references and methods. The default is Closure.OWNER_FIRST
resolveStrategy - The resolve strategy to setBuilds a trampolined variant of the current closure. To prevent stack overflow due to deep recursion, functions can instead leverage the trampoline mechanism and avoid recursive calls altogether. Under trampoline, the function is supposed to perform one step of the calculation and, instead of a recursive call to itself or another function, it return back a new closure, which will be executed by the trampoline as the next step. Once a non-closure value is returned, the trampoline stops and returns the value as the final result. Here is an example:
def fact
fact = { n, total ->
n == 0 ? total : fact.trampoline(n - 1, n * total)
}.trampoline()
def factorial = { n -> fact(n, 1G)}
println factorial(20) // => 2432902008176640000
args - Parameters to the closure, so as the trampoline mechanism can call itBuilds a trampolined variant of the current closure. To prevent stack overflow due to deep recursion, functions can instead leverage the trampoline mechanism and avoid recursive calls altogether. Under trampoline, the function is supposed to perform one step of the calculation and, instead of a recursive call to itself or another function, it return back a new closure, which will be executed by the trampoline as the next step. Once a non-closure value is returned, the trampoline stops and returns the value as the final result.
Copyright © 2003-2024 The Apache Software Foundation. All rights reserved.